# Example 4.1
MKS(kN, kN m, deg)
r[1] = 6 m
f = polarvec(40 kN, 30 deg)
M = cross(r, f)


# Example 4.2
MKS(mm, kN, kN m, deg)

r0 = [0, 0, 0] mm
f0[2] = -3 kN

r1 = [300, 300] mm
f1[2] = -2 kN

r2 = [700] mm
f2 = [5] kN

r3 = [700, 300] mm
f3 = PolarVec(4 kN, 30 deg)

sumf = f0 + f1 + f2 + f3
sumM = cross(r0, f0) + cross(r1, f1) + cross(r2, f2) + cross(r3, f3)



# Example 4.3
FPS(deg)
w[2] = -300 lb
rw = [2, 2] ft

rb = [0, 7] ft
ra = [4, 4] ft
ub = (rb - ra) / mag(rb - ra)
BEGIN
  t = 1 lb
  sumM = cross(rw, w) + cross(ra, t * ub)
END
solve(sumM[3], t)


# Example 4.4
MKS(N m, deg)
r = [5, 2] m
f = PolarVec(400 N, -30 deg)
M = cross(r,f)


# Example 4.5
FPS
ra = [0, 6, 5] ft
rb = [11, 0, 4] ft
rc = [7, 7, 0] ft
uc = (rc - rb) / mag(rc - rb)
f = 90 lb * uc

MA = cross(rb - ra, f)
x = mag(MA) / mag(f)


# Example 4.6
MKS(kN, kN m, deg)
ra = [4, 0, 6] m
rb = [0, 4, 8] m
rc = [6, 3, 0] m
ub = (rb - ra) / mag(rb - ra)
uc = (rc - ra) / mag(rc - ra)
fb = 10 kN * ub
fc = 20 kN * uc
r0 = [0, 0, 0] m
M = cross(rb - r0, fb) + cross(rc - r0, fc)



# Example 4.7
FPS
r = [4, 0, 3] ft
f = [0, 50, 0] lbf
M = cross(r,f)


# Example 4.8
MKS(kN, kN m)
ra = [4, 2, 2] m
rb = [0, 0, 3] m
rc = [0, 4, 0] m
f = [-2, 6, 3] kN
r = ra - rb
M = cross(r, f)
u = (rc - rb) / mag(rc - rb)
dot(M,u)

# Example 4.9
MKS(N, N m)
r = [-0.18 , 0.28, 0.1] m
f = [0, 4, 32] N
M = cross(r,f)
2 * M


# Example 4.10
MKS(N, N m)
f = [10, -4] N
r1 = [6, 6, 0] m
r2 = [8, 3, 0] m
M = cross(r2-r1, f)

# Example 4.11
FPS
rb = [4, 0] ft
rc = [8, 0] ft
M0 = 200 ft lb
fb = -M0 / mag(rb)


# Example 4.12
MKS(N, N m)
r1 = [0, 2] m
f1 = [0, 0, 20 ] N
r2 = [4, 0] m
q = 30 deg
f2 = 30 N * [0, cos(q), sin(q)]
r3 = [8, 0] m
f3 = -f2
M = cross(r1,f1) + cross(r2,f2) + cross(r3, f3)



# Example 4.13
MKS(N, N m)
M1 = 0 N m
M2 = -50 N m + 50 N * 0.5 m
M3 = -50 N m + 50 N * 1 m


# Example 4.14
FPS
M1 = -20 ft lb - 10 lb * 8 ft
M2 = -25 ft lb - 15 lb * 5 ft



# Example 4.15
MKS(kN, kN m)
fa = [-10, 10, -15] kN
fb = [30, 5, 10] kN
rb = [6, 0, 0] m
M0 = [-90, 150, 60] kN m
fc = [10, -5, 5] kN
fd = [10, 20, -10] kN
rd = [6, 3, 3] m

(fa + fb) - (fc + fd)
M1 = M0 + cross(rb, fb)
M2 = cross(rd, fd)


# Example 4.16
FPS
ra = [4, 4, 2] ft
fa = [10,4, -3] lb
rb = [8, 0, 6] ft
fb = fa
M = cross(ra, fa) - cross(rb, fb)



# Example 4.17
MKS(kN, kN m)

r1 = [3 ] m
f1 = [0, 30 ] kN
r2 = [5] m
f2 = [20, 20] kN
M0[3] = 210 kN m

f = f1 + f2
M = M0 + cross(r1, f1) + cross(r2, f2)


# Example 4.18
MKS(kN, kN m)
fa = [-10, 10, -15] kN
fb = [30, 5, 10] kN
Mc = [-90, 150, 60] kN m
rp = [4, 3, -2] m
rb = [6, 0, 0] m
f = fa + fb
M = Mc + cross(rb, fb) - cross(rp, f)

# Example 4.19
FPS
r1 = [-3, 0, -2] ft
f1 = [0, 20] lb
r2 = [2, 0, 4] ft
f2 = [0, -10] lb
r3 = [6, 0, 2] ft
f3 = [0, 30] lb
f = f1 + f2 + f3
M0 = cross(r1,f1) + cross(r2,f2) + cross(r2,f3)
BEGIN
  x = 1 ft
  y = 0 ft
  z = 1 ft
  e = cross([x, y, z], f) - M0
END
solve(e[1], e[3],x , z)



# Example 4.20
MKS(N, N m)
f = [3, 6, 2] N
M = [12, 4, 6] N m
u = f / mag(f)
Mp = dot(u, M) * u
Mn = M - Mp
BEGIN
 x = 0.5 m
 y = 0 m
 z = -1.3 m
 e = cross([x, y, z], f) - Mn
END
solve(e[2], e[3], x, z)


# Example 4.21
MKS(mm, N, N m, deg)
r = 200 mm
roc = 1 m
f0 = [10, 10, -5] N
q = 20 deg

BEGIN
  a = 10 deg
  f = sin(q) * f0
  eoc = [roc * cos(q) , roc * sin(q), 0]
  rca = roc * [cos(a) * sin(q), -cos(a) * cos(q), -sin(a)]
  Moc = dot(eoc, cross(rca, f)) * eoc
  y = mag(Moc)
END
max(y, a)

# Homework Problems:

TBD